Boost converter based on near-ideal switches.
*P. Krein, 2015
*This example simulation was used to generate
*Fig. 3.35 in the second edition of
*Elements of Power Electronics, Oxford, 2015.
*
.opt acct nomod nopage reltol=.001 itl5=0 itl4=100 numdgt=8
.width out=132
.temp 30
.tran 0.01us 500us 300us 0.1us uic
*
*The gate signal.  This is an uncontrolled converter
*   with fixed duty ratio.  The switch on-time
*   has been selected to produce 24 V output.  A small resistor
*   connects the waveform to the device gate.
vq 120 0 pulse(0 12 0 0 0 5.847u 25u)
rq 120 40 5
*Input dc supply at node 3.
vcc 3 0 dc 8
*
*Input inductor with small resistive parasitic.
*This simulation happens to be in DCM, so a 0 initial
*   condition is most suitable.
l1 102 2 2.67uH ic=0A
rl 3 102 0.0001
*
*Low resistance diode model for near-ideal device.
.model dio D(Is=0.1n Rs=0.0001)
dout 2 1 dio
*
*Capacitor with low series resistance.
resr 1 201 0.0001
cout 201 0 1000uf ic=24V
*
*The load is the output at node 1.
rload 1 0 24
*The main switch, controlled by the gate signal at node 40.
sm1 2 0 40 0 sideal
*
*N-type and P-type switch models.  Only N used in this example.
.model sideal VSWITCH(Ron=0.002 Roff=1E7 Von=5 Voff=4)
.model sinv VSWITCH(Ron=0.002 Roff=1e7 Von=-0.5 Voff=-1.0)
.probe
.print tran v(1),v(2),i(l1),i(dout),i(cout)
.end