Cockcroft-Walton Multiplier, 2 stages.
*P. Krein, Elements of Power Electronics, second edition, 2015.
*See Fig. 4.65.
.opt acct nomod nopage reltol=.001 itl5=0
.width out=80
.temp 30
.tran 10us 0.8s 0 800us
vin 100 0 sin(0 170 60 0 0 0)
*With 120 V rms input (170 V peak), the multiplier should
*   develop 340 V per stage.  At no load, it should produce
*   680 V in this example.  Low ripple will require an 
*   RC time constant much longer than 1/60 s 
*   to avoid significant droop.
c1 0 1 0.01uF			;Capacitor labels as in Fig. 4.65.
c3 1 10 0.01uF
c2 100 2 0.01uF
c4 2 4 0.01uF
.model dio D(Is=10p Rs=0.1)	;Near-ideal diode
d1 0 2 dio				;Diode labels as in Fig. 4.65.
d2 2 1 dio
d3 1 4 dio
d4 4 10 dio
*The output node is 10.  Vout is measured from 10 to 0.
*The outout is sustained by a series combination of
*   C1 and C3.  For instance, 10% droop should require
*   Rload x C1/2 to be at least ten times 1/60.
*   However, in the multiplier, the ripple  adds among stages.
*   Here is a sample load Rload = 67 M.
*   It generates too much ripple, but is a very
*   instructive first test.
rload 10 0 67000k
*
*It is also suggested that V(1), V(2), and V(4) be viewed
*   to show how the output builds up over time 
*   and how the multiplier acts.
.probe
.end