Basic diode-capacitor rectifier, plus L
*The industor is connected at the input.
*This is a diode bridge circuit.
.opt acct nomod nopage reltol=.001 itl5=0 itl4=100
.width out=80
.temp 30
.tran 100us 200ms 180ms 50us uic	;Show output after 180ms,
*							  steady state conditions.
*Three different inductor values are tested.  None is
*   high enough to maintain constant current flow.
.param linv=1e-6
.step param linv list 2e-6 2e-4 2e-3
*
*Node 101 is the sinusoidal input.
*The inductor is in series with the input, connecting into
*   the diode bridge.
*Nodes 102 and 0 are the bridge input.
*Nodes 1, 2 are the bridge output.
vac 101 0 sin(0 14 60)	;Input source
lin 101 102 {linv} ic=0A	;Input-side inductor, strat from 0A.
d11 102 1 dio			;Diode bridge
d21 0 1 dio
d12 2 102 dio
d22 2 0 dio
*
*Add a zero volt source as an output current probe.
vi 1 11 0				;Output current link
cout 11 2 22000uF ic=10V	;Output capacitor
rload 11 2 6			;Output load resistor
*
*SPICE struggles with a near-ideal diode bridge.  These
*   two resistors help avoid the problem of floating nodes.
*This would not be necessary for a half-wave simulation.
rnofloat 1 0 1e6
rnofloa2 2 0 1e6
*
*A near-ideal diode model.
.model dio D(is=1e-9 rs=0.001)	;Near-ideal diode
.probe
.end